mrrl-system-config

version_path.awk (1010B)

---

 function get_package_path(name) {
 	if(!("pthbs_path_"name in ENVIRON)) {
 		print "version_path.awk: Fatal: path for package '"name"' not specified" >"/dev/stderr"
 		exit 2
 	}
 	return ENVIRON["pthbs_path_"name]
 }
 
 function exec_path(name) {
 	if(!length(execfile)) {
 		print "version_path.awk: Fatal: 'execfile' variable not specified" >"/dev/stderr"
 		exit 2
 	}
 	print name >>execfile
 	return get_package_path("system-config") "/deps/command/" name
 }
 
 function q(s) {  # quote string for execline
 	gsub(/\\/, "\\\\", s)
 	gsub(/\n/, "\\n", s)
 	gsub(/\"/, "\\\"", s)
 	return "\"" s "\""
 }
 
 function qexec(s) {
 	return q(exec_path(s))
 }
 
 function config_path(name) {
 	return get_package_path("system-config") "/config/" name
 }
 
 function qconfig(s) {
 	return q(config_path(s))
 }
 
 function env_enter(name) {
 	return get_package_path(name)"/command/pthbs-enter"
 }
 
 function qenv(s) {
 	return q(env_enter(s))
 }
 
 function env_el(s) {
 	return env_enter(s)"-execlineb"
 }
 
 function env_sh(s) {
 	return env_enter(s)"-sh"
 }