mrrl-system-config

parse_fs.include.awk (7289B)

---

 BEGIN{
 	param_validator["source"] = ".+"
 	param_validator["type"] = "[a-z0-9._]+"
 	param_validator["options"] = ".*"
 	param_validator["bundles"] = "[^ 	]+"
 	param_validator["down"] = "(umount|readonly|keep)"
 	param_validator["mkdir"] = "(true|false)"
 	param_validator["premounted"] = "(true|false)"
 	param_validator["service_name"] = "[^ 	/]+"
 	param_validator["dependencies"] = "[^/]*"
 	param_validator["extra_dependencies"] = "[^/]+"
 	fail = 0
 }
 
 #function q(s) {  # quote string for execline
 #	gsub(/\\/, "\\\\", s)
 #	gsub(/\n/, "\\n", s)
 #	gsub(/\"/, "\\\"", s)
 #	return "\"" s "\""
 #}
 
 function fatal_mtp(s){
 	print mountpoints[mtp] ": Error: " s "  [" mtp "]" >"/dev/stderr"
 	fail=1
 	exit 1
 }
 
 function fatal_parse(s){
 	print FILENAME ":" FNR ": Error: " s >"/dev/stderr"
 	fail=1
 	exit 1
 }
 
 function dbg(s){
 	if(debug) {
 		print("#" s)
 	}
 }
 
 function is_parent(child_path, parent_path) {
 	if(child_path == "/") {
 		return 0
 	}
 	if(parent_path == "/") {
 		return 1
 	}
 	parent_path = parent_path "/"
 	return substr(child_path, 1, length(parent_path)) == parent_path
 }
 # function is_parent(child_path, parent_path,  result) {
 # 	result = is_parent_(child_path, parent_path)
 # 	dbg("++ '" parent_path "' " (result?"is":"is NOT") " parent of '" child_path "'")
 # 	return result
 # }
 
 function mtp_get(mtp_x, name) {
 	if(!((mtp_x,name) in params)) {
 		fatal_mtp("parameter '" name "' not set")
 	}
 	if(name in param_validator) {
 		if(params[mtp_x,name] !~ ("^" param_validator[name] "$")) {
 			fatal_mtp("Internal: parameter '" mtp_x "','" name "' set to unrecognized value '" params[mtp_x,name] "'")
 		}
 	} else if (!(name in param_extras)) {
 		fatal_mtp("Internal: parameter name '" mtp_x "','" name "' not known")
 	}
 	return params[mtp_x,name]
 }
 
 function get(name) {
 	return mtp_get(mtp, name)
 }
 
 # execline quoted get function
 function qget(name) {
 	if(name == "") {
 		return q(mtp)
 	}
 	if(name == "remount_options") {
 	return get("options") == "defaults" ? "remount" : q("remount," get("options"))
 	}
 	return q(get(name))
 }
 
 function set(name, value) {
 	if(name in param_validator) {
 		if(value !~ ("^" param_validator[name] "$")) {
 			fatal_mtp("Internal: tried to set '" name "' set to unrecognized value '" value "'")
 		}
 	} else if (!(name in param_extras)) {
 		fatal_mtp("Internal: parameter name '" name "' not known")
 	}
 	params[mtp,name] = value
 }
 
 function set1(name, value) {
 	if((mtp,name) in params) {
 		fatal_mtp("parameter '" name "' already set to '" params[mtp,value] "', tried to assign '" value "'")
 	}
 	set(name, value)
 }
 
 function boolean(name) {  # Check boolean parameter
 	return get(name) == "true"
 }
 
 function down(is_value) {  # Check "down" parameter
 	return is_value == get("down")
 }
 
 function down_umount() { return down("umount") }
 function down_keep() { return down("keep") }
 function down_readonly() { return down("readonly") }
 
 function dependencies(     s, i) {
 	s = ""
 	for(i=1; i<=dn; i++) {
 		s = s "\t" ds[i] "\n"
 	}
 	return s
 }
 
 function find_topmost_mount(     found, mtp2) {
 	found = ""
 	for(mtp2 in mountpoints) {
 		if(length(mtp2) > length(found) && is_parent(mtp, mtp2)) {
 			found = mtp2
 		}
 	}
 	if(!length(found)) {
 		# consider if this should be error for mtp != "/"
 		return ""
 	}
 	dbg(" dep FOUND: '" found "' -> svc: '" mtp_get(found, "service_name") "'")
 	if(!boolean("mkdir")) {
 		if(mtp_get(found,"premounted") == "true" && mtp_get(found,"down") != "umount") {
 			# Dependency would be superfluous
 			return ""
 		}
 	}
 	# fatal_mtp("FOUND: '" found "' -> svc: '" mtp_get(found, "service_name") "'")
 	return params[found, "service_name"]
 }
 
 function process_record(    name, i, mtp2) {
 	dbg("## ----------------------------------------------------------------------")
 	if(!((mtp,"premounted") in params)) {
 		set1("premounted", "false")
 	}
 
 	if(!((mtp,"mkdir") in params)) {
 		set1("mkdir", boolean("premounted") ? "false" : "true")
 	}
 
 	if(!((mtp,"down") in params)) {
 		set1("down", "umount")
 	}
 
 	if(!((mtp,"options") in params)) {
 		set1("options", "rw")
 	}
 
 	# set1("dependencies", "foo bar")
 	if(((mtp,"dependencies") in params)) {
 		if(((mtp,"extra_dependencies") in params)) {
 			fatal_mtp("Define either 'extra_dependencies' or 'dependencies', not both")
 		}
 		dn = split(get("dependencies"), ds)
 
 	} else {
 		if(((mtp,"extra_dependencies") in params)) {
 			dn = split(get("extra_dependencies"), ds)
 		} else {
 			dn = 0
 		}
 		i = find_topmost_mount()
 		if(length(i)) {
 			dn += 1
 			ds[dn] = i
 		}
 
 	}
 
 	#print(">>> " mtp " <<< " ((mtp,"service_name") in params))
 	# if(!((mtp,"service_name") in params)) {
 	# It may be initialized by access from find_topmost_mount()
 	if(length(params[mtp,"service_name"]) == 0) {
 		if(mtp == "/") {
 			if(!boolean("premounted")) {
 				fatal_mtp("rootfs not set as premounted")
 			}
 			set("service_name", "rootfs")
 		} else {
 			svc_name = mtp
 			gsub("/", "-", svc_name)
 			set("service_name", "mount" svc_name)
 		}
 	}
 	svc_name = get("service_name")
 	if(svc_name !~ ("^" param_validator["service_name"] "$")) {
 		fatal_mtp("Service name '" svc_name "' not valid")
 	}
 	if(svc_name in services) {
 		fatal_mtp("Service name '" svc_name "' collides with mountpoint '" services[svc_name] "' defined at " mountpoints[services[svc_name]])
 	}
 	services[svc_name] = mtp
 
 	if(debug) {
 		printf("#>> mtp='%s'\n", mtp)
 		for(name in params) {
 			if(substr(name, 1, length(mtp)+1) == mtp SUBSEP) {
 				printf("#>> %s='%s'\n", substr(name, length(mtp)+1), params[name])
 			}
 		}
 	}
 
 	write_oneshot()
 
 	if((mtp,"bundles") in params) {
 		split(get("bundles"), bundle_list)
 		for(i in bundle_list) {
 			add_to_bundle(bundle_list[i], svc_name)
 		}
 		delete bundle_list
 	}
 
 	#delete params
 	mtp = ""
 }
 
 function process_bundles(    name) {
 	for(name in bundles) {
 		write_bundle(name)
 	}
 }
 
 function validate_mountpoint(    mtp2) {
 	if(mtp in mountpoints) {
 		fatal_parse("duplicate definition of mountpoint '" $0 "', previous definition at " mountpoints[$0])
 	}
 	if(mtp != "/" && mtp ~ "/$") {
 		fatal_parse("Trailing slash not allowed: '" mtp "'")
 	}
 	if(mtp ~ "/(|\\.|\\.\\.)/") {
 		fatal_parse("Mountpoint '" mtp "' is not canonical absolute path")
 	}
 	for(mtp2 in mountpoints) {
 		if(is_parent(mtp2, mtp)) {
 			fatal_parse("mountpoint '" mtp "' defined after implicit reverse dependency '" mtp2 "' located at " mountpoints[mtp2])
 		}
 	}
 }
 
 # Skip comments
 /^[ \t]*#/{ next }
 
 # mountpoint (aka fs_file in fstab)
 /^\//{
 	if(mtp) {
 		process_record()
 	}
 	mtp=$0
 	validate_mountpoint()
 	mountpoints[mtp] = FILENAME ":" FNR
 	next
 }
 
 # All other lines
 {
 	line=$0
 	m = match(line, /^[ \t]+/)
 	if(m) {
 		# Strip leading whitespace
 		line = substr(line, m+RLENGTH)
 	}
 	if(length(line) == 0) {
 		# Skip empty lines
 		next
 	}
 	m = match(line, /=/)
 	if(m) {
 		name = substr(line, 1, m-1)
 		value = substr(line, m+RLENGTH)
 		if((mtp, name) in params) {
 			fatal_parse("Duplicate definition of parameter '" name "'")
 		}
 		if(!(name in param_validator)) {
 			fatal_parse("Unrecognized parameter '" name "'")
 		}
 		if(value !~ ("^" param_validator[name] "$")) {
 			fatal_parse("Invalid value for parameter '" name "': '" value "'")
 		}
 		params[mtp,name] = value
 	} else {
 		fatal_parse("missing '=' in parameter definition")
 	}
 }
 
 END{
 	if(fail) {
 		exit fail
 	}
 	if(mtp) {
 		process_record()
 	}
 	print_bundles()
 }