1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
#!/bin/zsh
setopt no_unset warn_create_global
typeset -gA clipboards
typeset -g map=/run/display-container-map
#set -x

get-clip() {
	local sel out name=$1
	local -a env=( env )
	[[ -f /run/Xauthority.${DISPLAY#:} ]] && \
		env+=( XAUTHORITY=/run/Xauthority.${DISPLAY#:} )
	for sel in CLIPBOARD PRIMARY; do
		out=$( $env xclip -o -sel $sel ) && \
			[[ -n $out ]] &&
			clipboards[${sel:l}@$name]=$out
	done
}

scan() {
	local sock
	local -a found
	for sock in /tmp/.X11-unix/X*; do
		found=( $map/${${sock:t}#X}=*(N) )
		DISPLAY=:${sock##*/X} get-clip ${${found[1]:-${sock:t}}##*=}
	done
}
#typeset -f -t scan

print-clip() {
	local name content
	for name content in "${(kv@)clipboards}"; do
		printf '>> %s <<\n%s\n\n' $name $content
	done
}

print-clip-0() {
	local name content
	for name content in "${(kv@)clipboards}"; do
		printf '%s\0' $name $content
	done
}

main() {
	scan
	if (($#)) && [[ $1 == -0 ]]; then
		print-clip-0
	else
		print-clip
	fi
}
main "$@"