1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
let s:suite = themis#suite('parser')
let s:assert = themis#helper('assert')

function! s:suite.escape() abort
  call s:assert.equals(
        \ vimproc#parser#split_args('echo "\""'),
        \ ['echo', '"'])
  call s:assert.equals(
        \ vimproc#parser#split_args('echo "\`test\`"'),
        \ ['echo', '`test`'])
  call s:assert.equals(vimproc#shellescape('hoge'), "'hoge'")
  call s:assert.equals(vimproc#shellescape('ho''ge'), "'ho''ge'")
endfunction

function! s:suite.comment() abort
  call s:assert.equals(
        \ vimproc#parser#split_args('echo file#1.txt'),
        \ ['echo', 'file#1.txt'])
  call s:assert.equals(
        \ vimproc#parser#split_args('echo file #1.txt'),
        \ ['echo', 'file'])
endfunction

function! s:suite.quote() abort
  let is_catched = 0
  try
    call vimproc#parser#split_args('echo "\"')
  catch /^Exception: Quote/
    let is_catched = 1
  endtry
  call s:assert.equals(is_catched, 1)
endfunction

function! s:suite.join() abort
  let is_catched = 0
  try
    call vimproc#parser#split_args('echo \')
  catch /^Exception: Join to next line/
    let is_catched = 1
  endtry
  call s:assert.equals(is_catched, 1)
endfunction

function! s:suite.parse_statements() abort
  let statements =
        \ vimproc#parser#split_statements(
        \ '"/usr/bin/clang++" --std=c++0x `pkg-config'.
        \ ' --libs opencv` "/home/me/opencv/capture.cpp"'.
        \ ' -o "/home/me/opencv/capture" && "/home/me/opencv/capture"')
  call s:assert.equals(statements,
        \ ['"/usr/bin/clang++" --std=c++0x `pkg-config'.
        \ ' --libs opencv` "/home/me/opencv/capture.cpp"'.
        \ ' -o "/home/me/opencv/capture" ', ' "/home/me/opencv/capture"'
        \ ])
endfunction

function! s:suite.backquote() abort
  call s:assert.equals(
        \ vimproc#parser#split_args('echo `echo "hoge" "piyo" "hogera"`'),
        \ [ 'echo', 'hoge', 'piyo', 'hogera' ])
  call s:assert.equals(
        \ vimproc#parser#split_args(
        \ 'echo "`curl -fs https://gist.github.com/raw/4349265/sudden-vim.py`"'),
        \ [ 'echo', system('curl -fs https://gist.github.com/raw/4349265/sudden-vim.py')])
endfunction

function! s:suite.slash_convertion() abort
  " For Vital.DateTime
  call s:assert.equals(vimproc#parser#split_args(
        \ printf('reg query "%s" /v Bias',
        \ 'HKLM\System\CurrentControlSet\Control\TimeZoneInformation')),
        \ ['reg', 'query',
        \  'HKLM\System\CurrentControlSet\Control\TimeZoneInformation',
        \  '/v', 'Bias'])
endfunction

function! s:suite.block_convertion() abort
  call s:assert.equals(vimproc#parser#parse_pipe(
        \ 'grep -inH --exclude-dir={foo} -R vim .')[0].args,
        \ ['grep', '-inH',
        \  '--exclude-dir=f', '--exclude-dir=o',
        \  '-R', 'vim', '.'])
  call s:assert.equals(vimproc#parser#parse_pipe(
        \ 'grep -inH --exclude-dir={foo,bar,baz} -R vim .')[0].args,
        \ ['grep', '-inH',
        \  '--exclude-dir=foo', '--exclude-dir=bar', '--exclude-dir=baz',
        \  '-R', 'vim', '.'])
endfunction

function! s:suite.parse_redirection() abort
  call s:assert.equals(vimproc#parser#parse_pipe(
        \ 'echo "foo" > hoge\piyo'),
        \ [{ 'args' : ['echo', 'foo'], 'fd' :
        \  { 'stdin' : '', 'stdout' : 'hogepiyo', 'stderr' : '' }}])
endfunction

" vim:foldmethod=marker:fen: