1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
let s:suite = themis#suite('fopen')
let s:assert = themis#helper('assert')
call themis#helper('command').with(s:)

let s:filename = 'test.txt'
let s:contents = ['foo', 'bar']

function! s:suite.before_each() abort
  call writefile(s:contents, s:filename, 'b')
endfunction

function! s:suite.after_each() abort
  if filereadable(s:filename)
    call delete(s:filename)
  endif
endfunction

function! s:suite.read() abort
  let file = vimproc#fopen(s:filename)
  let res = file.read()

  call s:assert.true(file.is_valid)

  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(
        \ readfile(s:filename),
        \ split(res, '\r\n\|\r\|\n'))
endfunction

function! s:suite.read_lines() abort
  let file = vimproc#fopen(s:filename, 'r')
  let res = file.read_lines()

  call s:assert.true(file.is_valid)

  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(
        \ readfile(s:filename, 'b'), res)
endfunction

function! s:suite.read_line() abort
  let file = vimproc#fopen(s:filename, 'r', 0)
  let res = []
  while !file.eof
    let res += [file.read_line()]
  endwhile

  call s:assert.true(file.is_valid)

  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(readfile(s:filename), res)
endfunction

function! s:suite.write() abort
  let file = vimproc#fopen(s:filename, 'w')
  let res = "hello\nvimproc\n.vim"

  call s:assert.true(file.is_valid)

  call file.write(res)
  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(
        \ readfile(s:filename),
        \ split(res, '\r\n\|\r\|\n'))
endfunction

function! s:suite.append() abort
  let file = vimproc#fopen(s:filename, 'a')
  let res = "\nhello\nvimproc\n.vim"

  call s:assert.true(file.is_valid)

  call file.write(res)
  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(
        \ readfile(s:filename),
        \ s:contents + split(res, '\r\n\|\r\|\n'))
endfunction

function! s:suite.read_write() abort
  let file = vimproc#fopen(s:filename, 'r+')
  let res = file.read()

  call s:assert.equals(
        \ readfile(s:filename),
        \ split(res, '\r\n\|\r\|\n'))

  call s:assert.true(file.is_valid)

  let res = "\nhello\nvimproc\n.vim"
  call file.write(res)
  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(
        \ readfile(s:filename),
        \ s:contents + split(res, '\r\n\|\r\|\n'))
endfunction

function! s:suite.with_oflag() abort
  let file = vimproc#fopen(s:filename, 'O_RDONLY')
  let res = file.read()

  call s:assert.true(file.is_valid)

  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(
        \ readfile(s:filename),
        \ split(res, '\r\n\|\r\|\n'))

  let file = vimproc#fopen(s:filename, 'O_WRONLY|O_TRUNC')
  let res = "hello\nvimproc\n.vim"
  call file.write(res)

  call s:assert.true(file.is_valid)

  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(
        \ readfile(s:filename),
        \ split(res, '\r\n\|\r\|\n'))

  let file = vimproc#fopen(s:filename, 'O_RDWR|O_APPEND')
  let res2 = "\nworld\n!"
  call file.write(res2)

  call s:assert.true(file.is_valid)

  call file.close()

  call s:assert.false(file.is_valid)

  call s:assert.equals(
        \ readfile(s:filename),
        \ split(res . res2, '\r\n\|\r\|\n'))
endfunction

function! s:suite.invalid_fmode() abort
  let file = vimproc#fopen(s:filename, 'r')

  Throws /write() error/ file.write('foo')

  call file.close()

  call s:assert.equals(readfile(s:filename), s:contents)

  let file = vimproc#fopen(s:filename, 'w')

  Throws /read() error/ file.read()

  call file.close()

  call s:assert.true(empty(readfile(s:filename)))
endfunction

" vim:foldmethod=marker:fen: