1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
"=============================================================================
" FILE: tab.vim
" AUTHOR:  Shougo Matsushita <Shougo.Matsu@gmail.com>
" License: MIT license  {{{
"     Permission is hereby granted, free of charge, to any person obtaining
"     a copy of this software and associated documentation files (the
"     "Software"), to deal in the Software without restriction, including
"     without limitation the rights to use, copy, modify, merge, publish,
"     distribute, sublicense, and/or sell copies of the Software, and to
"     permit persons to whom the Software is furnished to do so, subject to
"     the following conditions:
"
"     The above copyright notice and this permission notice shall be included
"     in all copies or substantial portions of the Software.
"
"     THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
"     OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
"     MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
"     IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
"     CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
"     TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
"     SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
" }}}
"=============================================================================

let s:save_cpo = &cpo
set cpo&vim

function! unite#sources#tab#define() abort "{{{
  return s:source
endfunction"}}}

let s:source = {
      \ 'name' : 'tab',
      \ 'description' : 'candidates from tab list',
      \ 'syntax' : 'uniteSource__Tab',
      \ 'hooks' : {},
      \ 'default_kind' : 'tab',
      \}

function! s:source.gather_candidates(args, context) abort "{{{
  let list = range(1, tabpagenr('$'))
  let arg = get(a:args, 0, '')
  if arg ==# 'no-current'
    call filter(list, 'v:val != tabpagenr()')
  endif

  let candidates = []
  for i in list
    " Get current window buffer in tabs.
    let bufnr = tabpagebuflist(i)[tabpagewinnr(i) - 1]

    let bufname = unite#util#substitute_path_separator(
          \ (i == tabpagenr() ?
          \       bufname('#') : bufname(bufnr)))
    if bufname == ''
      let bufname = '[No Name]'
    endif

    if exists('*gettabvar')
      " Use gettabvar().
      let title = gettabvar(i, 'title')
      if title != ''
        let title = '[' . title . ']'
      endif

      let cwd = unite#util#substitute_path_separator(
            \ (i == tabpagenr() ? getcwd() : gettabvar(i, 'cwd')))
      if cwd !~ '/$'
        let cwd .= '/'
      endif
    else
      let title = ''
      let cwd = ''
    endif

    let abbr = i . ': ' . title
    if cwd != ''
      if stridx(bufname, cwd) == 0
        let bufname = bufname[len(cwd) :]
      endif
      let abbr .= (title != '' ? ' ' : '') . bufname

      let abbr .= ' (' . substitute(cwd, '.\zs/$', '', '') . ')'
    else
      let abbr .= bufname
    endif

    let wincnt = tabpagewinnr(i, '$')
    if i == tabpagenr()
      let wincnt -= 1
    endif
    if wincnt > 1
      let abbr .= '{' . wincnt . '}'
    endif
    let abbr .= getbufvar(bufnr('%'), '&modified') ? '[+]' : ''

    if len(tabpagebuflist(i)) > 1
      " Get tab windows list.
      for [winnr, bufnr] in map(tabpagebuflist(i), "[v:key, v:val]")
        let abbr .= "\n" . printf('%s %d: %s', repeat(' ', 1), (winnr+1),
              \ (bufname(bufnr) == '' ? '[No Name]' : bufname(bufnr)))
      endfor
    endif

    call add(candidates, {
          \ 'word' : abbr,
          \ 'is_multiline' : 1,
          \ 'action__tab_nr' : i,
          \ 'action__directory' : cwd,
          \ })
  endfor

  return candidates
endfunction"}}}
function! s:source.complete(args, context, arglead, cmdline, cursorpos) abort "{{{
  return ['no-current']
endfunction"}}}
function! s:source.hooks.on_syntax(args, context) abort "{{{
  syntax match uniteSource__Tab_title /\[.\{-}\]/
        \ contained containedin=uniteSource__Tab
  highlight default link uniteSource__Tab_title Function
  syntax match uniteSource__Tab_directory /(.\{-})/
        \ contained containedin=uniteSource__Tab
  highlight default link uniteSource__Tab_directory PreProc
endfunction"}}}

let &cpo = s:save_cpo
unlet s:save_cpo

" vim: foldmethod=marker