1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
"=============================================================================
" FILE: guicmd.vim
" AUTHOR:  Shougo Matsushita <Shougo.Matsu@gmail.com>
" License: MIT license  {{{
"     Permission is hereby granted, free of charge, to any person obtaining
"     a copy of this software and associated documentation files (the
"     "Software"), to deal in the Software without restriction, including
"     without limitation the rights to use, copy, modify, merge, publish,
"     distribute, sublicense, and/or sell copies of the Software, and to
"     permit persons to whom the Software is furnished to do so, subject to
"     the following conditions:
"
"     The above copyright notice and this permission notice shall be included
"     in all copies or substantial portions of the Software.
"
"     THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
"     OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
"     MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
"     IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
"     CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
"     TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
"     SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
" }}}
"=============================================================================

let s:save_cpo = &cpo
set cpo&vim

function! unite#kinds#guicmd#define() abort "{{{
  return s:kind
endfunction"}}}

let s:kind = {
      \ 'name' : 'guicmd',
      \ 'default_action' : 'execute',
      \ 'action_table': {},
      \ 'alias_table' : { 'ex' : 'nop' },
      \}

" Actions "{{{
let s:kind.action_table.execute = {
      \ 'description' : 'execute command',
      \ }
function! s:kind.action_table.execute.func(candidate) abort "{{{
  let args = [a:candidate.action__path]
  if has_key(a:candidate, 'action__args')
    let args += a:candidate.action__args
  endif

  if unite#util#is_windows()
    let args[0] = resolve(args[0])
  endif

  let cmdline = unite#util#is_windows() ?
        \ join(map(args, '"\"".v:val."\""')) :
        \ args[0] . ' ' . join(map(args[1:], "shellescape(v:val)"))

  if unite#util#is_windows()
    let cmdline = unite#util#iconv(cmdline, &encoding, 'char')
    silent execute ':!start' cmdline
  else
    call system(cmdline . ' &')
  endif
endfunction"}}}
let s:kind.action_table.edit = {
      \ 'description' : 'edit command args',
      \ }
function! s:kind.action_table.edit.func(candidate) abort "{{{
  let args = [a:candidate.action__path]
  if has_key(a:candidate, 'action__args')
    let args += a:candidate.action__args
  endif

  if unite#util#is_windows()
    let args[0] = resolve(args[0])
  endif

  let cmdline = unite#util#is_windows() ?
        \ join(map(args, '"\"".v:val."\""')) :
        \ args[0] . ' ' . join(map(args[1:], "''''.v:val.''''"))
  let cmdline = input('Edit command args :', cmdline, 'file')

  if unite#util#is_windows()
    silent execute ':!start' cmdline
  else
    call system(cmdline . ' &')
  endif
endfunction"}}}
"}}}

let &cpo = s:save_cpo
unlet s:save_cpo

" vim: foldmethod=marker