1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
"=============================================================================
" File    : autoload/unite/sources/outline/defaults/help.vim
" Author  : h1mesuke <himesuke@gmail.com>
" Updated : 2012-01-11
"
" Licensed under the MIT license:
" http://www.opensource.org/licenses/mit-license.php
"
"=============================================================================

" Default outline info for Vim Help
" Version: 0.1.2

function! unite#sources#outline#defaults#help#outline_info() abort
  return s:outline_info
endfunction

let s:Util = unite#sources#outline#import('Util')

" HEADING SAMPLES:
"
"== Level 1
"
"   ==========================================================================
"   Heading
"
"== Level 2
"
"   --------------------------------------------------------------------------
"   Heading
"
"== Level 3
"
"   1.1 Heading
"
"== Level 4-1
"
"   HEADING                                         *tag*
"
"== Level 4-2
"
"   HEADING ~
"                                                   *tag*

"---------------------------------------
" Sub Patterns

let s:pat_section_nr = '\d\+\.\d\+\s\+\S'
let s:pat_upper_word = '\u[[:upper:][:digit:]_]\+\>'
let s:pat_helptag = '\*[^*]\+\*'

"-----------------------------------------------------------------------------
" Outline Info

let s:outline_info = {
      \ 'heading-1': '^[-=]\{10,}\s*$',
      \ 'heading'  : '^\%(' . s:pat_section_nr . '\|' .
      \   s:pat_upper_word . '.*\%(' . s:pat_helptag . '\|\~\)\)',
      \ }

function! s:outline_info.create_heading(which, heading_line, matched_line, context) abort
  let heading = {
        \ 'word' : a:heading_line,
        \ 'level': 0,
        \ 'type' : 'generic',
        \ }

  let lines = a:context.lines

  if a:which ==# 'heading-1'
    let m_lnum = a:context.matched_lnum
    if a:matched_line =~ '^='
      let heading.level = 1
    elseif a:matched_line =~ '^-' && lines[m_lnum-1] !~ '\S'
      let heading.level = 2
    endif
  elseif a:which ==# 'heading'
    let h_lnum = a:context.heading_lnum
    if a:heading_line =~ '^' . s:pat_section_nr
      if a:heading_line =~ '\~\s*$'
        let heading.level = 3
      endif
    elseif a:heading_line =~ s:pat_helptag ||
          \ s:Util.neighbor_match(a:context, h_lnum, s:pat_helptag)
      let heading.level = 4
    endif
  endif

  if heading.level > 0
    let heading.word = s:normalize_heading_word(heading.word)
    if heading.word =~? '^Contents\s*$'
      let heading.level = 1
    endif
    return heading
  else
    return {}
  endif
endfunction

function! s:normalize_heading_word(word) abort
  let word = substitute(a:word, '\%(\~\|{{{\d\=\)\s*$', '', '')
  let word = substitute(word, s:pat_helptag, '', 'g')
  if word !~ '\l'
    let word = s:Util.String.capitalize(word, 'g')
  endif
  return word
endfunction