1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
"=============================================================================
" FILE: dictionary.vim
" AUTHOR:  Shougo Matsushita <Shougo.Matsu@gmail.com>
" License: MIT license  {{{
"     Permission is hereby granted, free of charge, to any person obtaining
"     a copy of this software and associated documentation files (the
"     "Software"), to deal in the Software without restriction, including
"     without limitation the rights to use, copy, modify, merge, publish,
"     distribute, sublicense, and/or sell copies of the Software, and to
"     permit persons to whom the Software is furnished to do so, subject to
"     the following conditions:
"
"     The above copyright notice and this permission notice shall be included
"     in all copies or substantial portions of the Software.
"
"     THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
"     OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
"     MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
"     IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
"     CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
"     TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
"     SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
" }}}
"=============================================================================

let s:save_cpo = &cpo
set cpo&vim

" Global options definition. "{{{
let g:neocomplete#sources#dictionary#dictionaries =
      \ get(g:, 'neocomplete#sources#dictionary#dictionaries', {})
"}}}

" Important variables.
if !exists('s:dictionary_cache')
  let s:dictionary_cache = {}
  let s:async_dictionary_list = {}
endif

function! neocomplete#sources#dictionary#define() abort "{{{
  return s:source
endfunction"}}}

let s:source = {
      \ 'name' : 'dictionary',
      \ 'kind' : 'keyword',
      \ 'mark' : '[D]',
      \ 'rank' : 4,
      \ 'hooks' : {},
      \}

function! s:source.hooks.on_init(context) abort "{{{
  augroup neocomplete "{{{
    autocmd FileType * call s:make_cache(&l:filetype)
  augroup END"}}}

  " Create cache directory.
  call neocomplete#cache#make_directory('dictionary_cache')

  " Initialize check.
  call s:make_cache(&l:filetype)
endfunction"}}}

function! s:source.hooks.on_final(context) abort "{{{
  silent! delcommand NeoCompleteDictionaryMakeCache
endfunction"}}}

function! s:source.gather_candidates(context) abort "{{{
  let list = []

  for ft in a:context.filetypes
    if !has_key(s:dictionary_cache, ft)
      call s:make_cache(ft)
    endif
    call neocomplete#cache#check_cache(
          \ 'dictionary_cache', ft,
          \ s:async_dictionary_list, s:dictionary_cache, 1)

    let list += get(s:dictionary_cache, ft, [])
  endfor

  return list
endfunction"}}}

function! s:make_cache(filetype) abort "{{{
  if !has_key(s:dictionary_cache, a:filetype)
        \ && !has_key(s:async_dictionary_list, a:filetype)
    call neocomplete#sources#dictionary#remake_cache(a:filetype)
  endif
endfunction"}}}

function! neocomplete#sources#dictionary#remake_cache(filetype) abort "{{{
  if !neocomplete#is_enabled()
    call neocomplete#initialize()
  endif

  let filetype = a:filetype
  if filetype == ''
    let filetype = neocomplete#get_context_filetype(1)
  endif

  if !has_key(s:async_dictionary_list, filetype)
    let s:async_dictionary_list[filetype] = []
  endif

  let pattern = neocomplete#get_keyword_pattern(filetype, s:source.name)
  for dictionary in neocomplete#sources#dictionary#get_dictionaries(filetype)
    let dictionary = neocomplete#util#substitute_path_separator(
          \ fnamemodify(dictionary, ':p'))
    if filereadable(dictionary)
      call neocomplete#print_debug('Make cache dictionary: ' . dictionary)
      call add(s:async_dictionary_list[filetype], {
            \ 'filename' : dictionary,
            \ 'cachename' : neocomplete#cache#async_load_from_file(
            \       'dictionary_cache', dictionary, pattern, 'D')
            \ })
    endif
  endfor
endfunction"}}}

function! neocomplete#sources#dictionary#get_dictionaries(filetype) abort "{{{
  let filetype = a:filetype
  if filetype == ''
    let filetype = neocomplete#get_context_filetype(1)
  endif

  " Make cache.
  let dictionaries = get(
        \ g:neocomplete#sources#dictionary#dictionaries, filetype, '')
  if has_key(g:neocomplete#sources#dictionary#dictionaries, '_')
    " Load global dictionaries.
    let dictionaries .= ',' .
          \ g:neocomplete#sources#dictionary#dictionaries['_']
  endif

  if dictionaries == '' && &l:dictionary != ''
    if ((filetype ==# 'nothing' && &filetype == '')
          \ || filetype ==# &filetype)
          \ && &l:dictionary !=# &g:dictionary
      let dictionaries = &l:dictionary
    endif
  endif

  return split(dictionaries, ',')
endfunction"}}}

let &cpo = s:save_cpo
unlet s:save_cpo

" vim: foldmethod=marker