1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
#!/bin/zsh
zparseopts -D \
	0=E -empty=E \
	p=P -pretend=P \
	h=H -help=H \
	v=V -verbose=F \
	d=D -debug=D

if [[ -n $H ]]; then cat <<END
usage: ${0:t} [options]

Deduplicate data using hardlinks using a report generated by duff or fdupes

options:
	-0 --empty          allow hardlinking empty files
	-p --pretend        print out the commands that would be performed
	-v --verbose        pass verbose flags to ln and mv
	-d --debug          enable debugging output
	-h --help           this help
END
	exit 0
fi

(($#D)) && set -x

zmodload zsh/stat
typeset -A stat inodes metas

while IFS= read line; do
	if [[ $line == [./]* ]]; then
		# got relative or absolute path
		zstat -LH stat $line || continue

		# check for empty files
		(( $stat[size] || $#E )) || continue

		# check if we handled this inode already
		ino=D$stat[device]_I$stat[inode]
		(( $+inodes[$ino] )) && continue

		# construct metadata that have to be same so we can hardlink
		meta=D$stat[device]_P$stat[mode]_U$stat[uid]_G$stat[gid]_M$stat[mtime]
		if (( $+metas[$meta] )); then
			tmp=$line:h/.tmp.$$.$line:t
			if [[ -e $tmp ]]; then
				echo >&2 "Temporary file $tmp already exists!"
				continue
			fi
			if (($#P)); then
				echo ln $V ${(qqq)metas[$meta]} ${(qqq)tmp} '&&' \
					mv $V ${(qqq)tmp} ${(qqq)line}
			else
				ln $V $metas[$meta] $tmp && mv $V $tmp $line || exit $?
			fi
		else
			inodes[$ino]=$line
			metas[$meta]=$line
		fi
	else
		# end of same-file block, clear known metadata
		inodes=( )
		meta=( )
	fi
done